AFsoft World

さて、ご質問ですがみなさんは目盛を使用しておられますか？木造住宅の設計の場合、結構重宝する機能なのですが（柱ピッチが910とか固定なので）同じ要しないに縮尺の違う詳細図とか書くときにはとてもいらいらします。
実際に平面等を各場合は1/100の図面で910ピッチ、目盛り機能にて1/2の点を見えるようにして柱、間柱とか、プラン＆実施設計をしております。この作業をする場合とても簡単に間取りの作成ができるのですが、レイヤーを変えて縮尺が違う図面を画く場合には点に反応して邪魔になり、拡大・縮小を繰り返したり、いちいち目盛をon・offをしなければ成りません。皆さんはどうされているのでしょうか？
提案ですが、目盛の範囲を決めれたらいいですね。図面いっぱいに無限に広がるんじゃなく、ここからここまでの範囲は910ピッチで点を、他の部分には違うピッチでとか（縮尺違っても点は同じピッチなので、レイヤーごとに決めれるとかでもいいかも。）

// sample10
// 補助線格子を書く
//
// 傾き角度は、JWWで作図する際の回転角で指定
// ５本毎に点線３で描く

#VAR
d = 100 ;*間隔
n1 = 10 ;*本数(上)
n2 = 10 ;*本数(下)
n3 = 10 ;*本数(左)
n4 = 10 ;*本数(右)
l // 作業用変数
i
x1
y1
x2
y2

#DRAW
// 数値チェック
#IF (d <= 0.0)
BEEP
MESSAGE "入力エラー","間隔の値は","正の値を入力して下さい。",0,0
#EXIT
#END

#IF ((n1 <= 0)||(n2 <= 0)||(n3 <= 0)||(n4 <= 0))
BEEP
MESSAGE "入力エラー","本数の値は","正の値を入力して下さい。",0,0
#EXIT
#END

// 作図開始

// ---------- 水平線 ----------
PEN 9,1,0 // 補助線色、実線、線幅0

// 基準
CAL x1 = - n3 * d
CAL y1 = 0.0
CAL x2 = n4 * d
CAL y2 = 0.0
LINE x1,y1, x2,y2

// 上側
CAL i = 1
CAL y1 = d
*LOOP1
CAL y2 = y1
PEN 9,9,0 // 補助線色、補助線種
#IF ((i%5) == 0)
PEN 9,4,0 // 補助線色、点線３
#END
LINE x1,y1, x2,y2

CAL y1 = y1 + d
CAL i = i + 1
#IF (i <= n1)
#GOTO *LOOP1
#END

// 下側
CAL i = 1
CAL y1 = -d
*LOOP2
CAL y2 = y1
PEN 9,9,0 // 補助線色、補助線種
#IF ((i%5) == 0)
PEN 9,4,0 // 補助線色、点線３
#END
LINE x1,y1, x2,y2

CAL y1 = y1 - d
CAL i = i + 1
#IF (i <= n2)
#GOTO *LOOP2
#END

// ---------- 垂直線 ----------
PEN 9,1,0 // 補助線色、実線、線幅0

// 基準
CAL x1 = 0.0
CAL y1 = n1 * d
CAL x2 = 0.0
CAL y2 = - n2 * d
LINE x1,y1, x2,y2

// 左側
CAL i = 1
CAL x1 = - d
*LOOP3
CAL x2 = x1
PEN 9,9,0 // 補助線色、補助線種
#IF ((i%5) == 0)
PEN 9,4,0 // 補助線色、点線３
#END
LINE x1,y1, x2,y2

CAL x1 = x1 - d
CAL i = i + 1
#IF (i <= n3)
#GOTO *LOOP3
#END

// 右側
CAL i = 1
CAL x1 = d
*LOOP4
CAL x2 = x1
PEN 9,9,0 // 補助線色、補助線種
#IF ((i%5) == 0)
PEN 9,4,0 // 補助線色、点線３
#END
LINE x1,y1, x2,y2

CAL x1 = x1 + d
CAL i = i + 1
#IF (i <= n4)
#GOTO *LOOP4
#END

// END