AFsoft World

たるんだ電線はどのように書くのですか？

// 懸垂曲線（カテナリー曲線）

#VAR
　X = 100　　;*横長さ
　a =　50　　;*係数a(a>0)
　n =　20　　;*分割数

　c
　w1
　w2
　x1
　y1
　x2
　y2
　xd
　yd

#DRAW
　LAYER　SetLineLay1
　PEN　SetLineCol1,SetLineLtp1,SetLineWid1

　CAL　xd = -X/2
　CAL　yd = -a*Cosh(xd/a)

　CAL　c = 0
　CAL　x1 = 0
　CAL　y1 = 0
　#WHILE (c < n)
　　CAL　x2 = x1 + X/n
　　CAL　w1 = x2 + xd
　　CAL　w2 = a*Cosh(w1/a)
　　CAL　y2 = w2 + yd

　　LINE　x1,y1,x2,y2
　　CAL　x1 = x2
　　CAL　y1 = y2
　　CAL　c = c + 1
　#END

さて、ご質問ですがみなさんは目盛を使用しておられますか？木造住宅の設計の場合、結構重宝する機能なのですが（柱ピッチが910とか固定なので）同じ要しないに縮尺の違う詳細図とか書くときにはとてもいらいらします。
実際に平面等を各場合は1/100の図面で910ピッチ、目盛り機能にて1/2の点を見えるようにして柱、間柱とか、プラン＆実施設計をしております。この作業をする場合とても簡単に間取りの作成ができるのですが、レイヤーを変えて縮尺が違う図面を画く場合には点に反応して邪魔になり、拡大・縮小を繰り返したり、いちいち目盛をon・offをしなければ成りません。皆さんはどうされているのでしょうか？
提案ですが、目盛の範囲を決めれたらいいですね。図面いっぱいに無限に広がるんじゃなく、ここからここまでの範囲は910ピッチで点を、他の部分には違うピッチでとか（縮尺違っても点は同じピッチなので、レイヤーごとに決めれるとかでもいいかも。）

// sample10
// 補助線格子を書く
//
// 傾き角度は、JWWで作図する際の回転角で指定
// ５本毎に点線３で描く

#VAR
d = 100 ;*間隔
n1 = 10 ;*本数(上)
n2 = 10 ;*本数(下)
n3 = 10 ;*本数(左)
n4 = 10 ;*本数(右)
l // 作業用変数
i
x1
y1
x2
y2

#DRAW
// 数値チェック
#IF (d <= 0.0)
BEEP
MESSAGE "入力エラー","間隔の値は","正の値を入力して下さい。",0,0
#EXIT
#END

#IF ((n1 <= 0)||(n2 <= 0)||(n3 <= 0)||(n4 <= 0))
BEEP
MESSAGE "入力エラー","本数の値は","正の値を入力して下さい。",0,0
#EXIT
#END

// 作図開始

// ---------- 水平線 ----------
PEN 9,1,0 // 補助線色、実線、線幅0

// 基準
CAL x1 = - n3 * d
CAL y1 = 0.0
CAL x2 = n4 * d
CAL y2 = 0.0
LINE x1,y1, x2,y2

// 上側
CAL i = 1
CAL y1 = d
*LOOP1
CAL y2 = y1
PEN 9,9,0 // 補助線色、補助線種
#IF ((i%5) == 0)
PEN 9,4,0 // 補助線色、点線３
#END
LINE x1,y1, x2,y2

CAL y1 = y1 + d
CAL i = i + 1
#IF (i <= n1)
#GOTO *LOOP1
#END

// 下側
CAL i = 1
CAL y1 = -d
*LOOP2
CAL y2 = y1
PEN 9,9,0 // 補助線色、補助線種
#IF ((i%5) == 0)
PEN 9,4,0 // 補助線色、点線３
#END
LINE x1,y1, x2,y2

CAL y1 = y1 - d
CAL i = i + 1
#IF (i <= n2)
#GOTO *LOOP2
#END

// ---------- 垂直線 ----------
PEN 9,1,0 // 補助線色、実線、線幅0

// 基準
CAL x1 = 0.0
CAL y1 = n1 * d
CAL x2 = 0.0
CAL y2 = - n2 * d
LINE x1,y1, x2,y2

// 左側
CAL i = 1
CAL x1 = - d
*LOOP3
CAL x2 = x1
PEN 9,9,0 // 補助線色、補助線種
#IF ((i%5) == 0)
PEN 9,4,0 // 補助線色、点線３
#END
LINE x1,y1, x2,y2

CAL x1 = x1 - d
CAL i = i + 1
#IF (i <= n3)
#GOTO *LOOP3
#END

// 右側
CAL i = 1
CAL x1 = d
*LOOP4
CAL x2 = x1
PEN 9,9,0 // 補助線色、補助線種
#IF ((i%5) == 0)
PEN 9,4,0 // 補助線色、点線３
#END
LINE x1,y1, x2,y2

CAL x1 = x1 + d
CAL i = i + 1
#IF (i <= n4)
#GOTO *LOOP4
#END

// END

// 長円＋文字
// =============================================
// (C)Copyright 2008 AFsoft All Rights Reserved.
// =============================================
#VAR
　mh =　5　　　　　　　;*文字高[mm]
　mw =　5　　　　　　　;*文字幅[mm]
　ms =　1　　　　　　　;*上下隙間[mm]
　s　　　　　　　　　　;*文字内容
　x 　　//横中心距離
　y 　　//縦の大きさ

　ii　　// 文字数
　w1
　w2
　w3
　w4
　w5

#DRAW
　#IF ((mh <= 0)||(mh > 1000))
　　　BEEP
　　　MESSAGE "入力エラー","文字高の値が異常です。","文字高の値を再入力して下さい。",0,w1
　　　#EXIT
　#END
　CAL　w1 = mh*0.1
　CAL　w2 = mh*10
　#IF ((mw < w1)||(mw > w2))
　　　BEEP
　　　MESSAGE "入力エラー","文字幅の値が異常です。","文字幅の値を再入力して下さい。",w1,w2
　　　#EXIT
　#END

　CAL　ii = LENGTH(s)
　#IF (SetMojiWid == 0)
　　　STRLEN ii,s
　　　CAL　ii = ii + ii
　#END

　CAL　x = mw*0.5*ii
　CAL　y = mh + ms*2.0

　LAYER SetLineLay1　　// 外径線
　PEN SetLineCol1,SetLineLtp1,SetLineWid1

　// 横線
　CAL　w1 = -x/2
　CAL　w2 =　y/2
　CAL　w3 =　x/2
　CAL　w4 = w2
　LINE w1,w2,w3,w4

　CAL　w2 = -y/2
　CAL　w4 = w2
　LINE w1,w2,w3,w4

　// 左右円弧
　CAL　w1 = -x/2
　CAL　w2 =　0
　CAL　w3 =　y/2
　CAL　w4 = 0.5*PI
　CAL　w5 = 1.5*PI
　ARC w1,w2,w3,w4,w5

　CAL　w1 = x/2
　CAL　w2 =　0
　CAL　w3 = y/2
　CAL　w4 = 1.5*PI
　CAL　w5 = 0.5*PI
　ARC w1,w2,w3,w4,w5

　CAL　w1 = 0
　CAL　w2 = 0
　TEXT w1,w2,mh,mw,0,5,s

// リンクその４
//　リンク１の角度をどんどん変えて作図させます
#VAR
　dmy1 = "---リンク(1)---"　　;dmy1
　px1 = 0　　　　;*位置X
　py1 = 0　　　　;*位置Y
　pa1s= 0　　　　;*開始角度[°]
　pa1e=45　　　　;*終了角度[°]
　pa1n= 5　　　　;*角度分割数
　ll1 =50　　　　;*リンク長さ
　lw1 =10　　　　;*リンク幅
　dmy2 = "---リンク(2)---"　　;dmy2
　px2　　　　　　;位置X
　py2　　　　　　;位置Y
　pa2　　　　　　;角度[°]
　ll2 =80　　　　;*リンク長さ
　lw2 =15　　　　;*リンク幅
　// 作業用
　n
　lay
　col
　pa1
　no
　px
　py
　ll
　lw
　pan
　w1
　w2
　w3
　w4
　w5
　w6
　w7
　w8

#DRAW
　CAL　n = 0
　CAL　lay = 0
　CAL　col = 1
　CAL　pa1 = pa1s
　#WHILE ( n <= pa1n )
　　LAYER　lay
　　PEN　col,SetLineLtp1,SetLineWid1
　　#GOTO *DRAW1
*RET
　　CAL　lay = lay + 1
　　#IF (lay > 15)
　　　　CAL　lay = 0
　　#END
　　CAL　col = col + 1
　　#IF (col > 8)
　　　　CAL　col = 1
　　#END
　　CAL　pa1 = pa1 + (pa1e - pa1s)/pa1n
　　CAL　n = n + 1
　#END

　#EXIT


// リンク２本を作図
*DRAW1
　CAL　no = 1
　CAL　pan = pa1/180.0*PI
　CAL　px = px1
　CAL　py = py1
　CAL　ll = ll1
　CAL　lw = lw1
　#GOTO *LINKDRAW
*RET1
　CAL　w1 = ll1*Sin(pan)
　CAL　w2 = ASIN(w1/ll2)
　CAL　w3 = -(pan + w2)
　CAL　pa2 = w3*180.0/PI

　CAL　no = 2
　CAL　px2 = px1 + ll1*Cos(pan)
　CAL　py2 = py1 + ll1*Sin(pan)
　CAL　pan = (pa1+pa2)/180.0*PI
　CAL　px = px2
　CAL　py = py2
　CAL　ll = ll2
　CAL　lw = lw2
　#GOTO *LINKDRAW
*RET2
　#GOTO *RET


// リンク１本を作図
//　　no = 1、2
*LINKDRAW
　CAL　w1 = px
　CAL　w2 = py
　CAL　w3 = lw/2.0
　CAL　w4 = pan + 0.5*PI
　CAL　w5 = pan + 1.5*PI
　ARC　w1,w2,w3,w4,w5

　CAL　w1 = px
　CAL　w2 = py + lw/2.0
　CAL　w3 = px + ll
　CAL　w4 = w2
　GETREV　w5,w6, w1,w2,px,py,pan
　GETREV　w7,w8, w3,w4,px,py,pan
　LINE　w5,w6,w7,w8

　CAL　w1 = px
　CAL　w2 = py - lw/2.0
　CAL　w3 = px + ll
　CAL　w4 = w2
　GETREV　w5,w6, w1,w2,px,py,pan
　GETREV　w7,w8, w3,w4,px,py,pan
　LINE　w5,w6,w7,w8

　CAL　w3 = px + ll
　CAL　w4 = py
　GETREV　w1,w2, w3,w4,px,py,pan
　CAL　w3 = lw/2.0
　CAL　w4 = pan + 1.5*PI
　CAL　w5 = pan + 0.5*PI
　ARC　w1,w2,w3,w4,w5

　#IF ( no == 1 )
　　#GOTO　*RET1
　#END
　#GOTO　*RET2

// リンクその３
//　リンク２の終点に制限を入れる事を考えます
//　リンク１の位置Yと同じになるようにします
//　　＝リンク２の角度を算出
#VAR
　dmy1 = "---リンク(1)---"　　;dmy1
　px1 = 0　　　　;*位置X
　py1 = 0　　　　;*位置Y
　pa1 = 0　　　　;*角度[°]
　ll1 =50　　　　;*リンク長さ
　lw1 =10　　　　;*リンク幅
　dmy2 = "---リンク(2)---"　　;dmy2
　px2　　　　　　;位置X
　py2　　　　　　;位置Y
　pa2　　　　　　;角度[°]
　ll2 =80　　　　;*リンク長さ
　lw2 =15　　　　;*リンク幅
　// 作業用
　no
　px
　py
　ll
　lw
　pan
　w1
　w2
　w3
　w4
　w5
　w6
　w7
　w8

#DRAW
　LAYER SetLineLay1　　// 外形線
　PEN SetLineCol1,SetLineLtp1,SetLineWid1

　CAL　no = 1
　CAL　pan = pa1/180.0*PI
　CAL　px = px1
　CAL　py = py1
　CAL　ll = ll1
　CAL　lw = lw1
　#GOTO *LINKDRAW
*RET1
　CAL　w1 = ll1*Sin(pan)
　CAL　w2 = ASIN(w1/ll2)
　CAL　w3 = -(pan + w2)
　CAL　pa2 = w3*180.0/PI

　CAL　no = 2
　CAL　px2 = px1 + ll1*Cos(pan)
　CAL　py2 = py1 + ll1*Sin(pan)
　CAL　pan = (pa1+pa2)/180.0*PI
　CAL　px = px2
　CAL　py = py2
　CAL　ll = ll2
　CAL　lw = lw2
　#GOTO *LINKDRAW
*RET2
　#EXIT


// リンク１本を作図
//　　no = 1、2
*LINKDRAW
　CAL　w1 = px
　CAL　w2 = py
　CAL　w3 = lw/2.0
　CAL　w4 = pan + 0.5*PI
　CAL　w5 = pan + 1.5*PI
　ARC　w1,w2,w3,w4,w5

　CAL　w1 = px
　CAL　w2 = py + lw/2.0
　CAL　w3 = px + ll
　CAL　w4 = w2
　GETREV　w5,w6, w1,w2,px,py,pan
　GETREV　w7,w8, w3,w4,px,py,pan
　LINE　w5,w6,w7,w8

　CAL　w1 = px
　CAL　w2 = py - lw/2.0
　CAL　w3 = px + ll
　CAL　w4 = w2
　GETREV　w5,w6, w1,w2,px,py,pan
　GETREV　w7,w8, w3,w4,px,py,pan
　LINE　w5,w6,w7,w8

　CAL　w3 = px + ll
　CAL　w4 = py
　GETREV　w1,w2, w3,w4,px,py,pan
　CAL　w3 = lw/2.0
　CAL　w4 = pan + 1.5*PI
　CAL　w5 = pan + 0.5*PI
　ARC　w1,w2,w3,w4,w5

　#IF ( no == 1 )
　　#GOTO　*RET1
　#END
　#GOTO　*RET2

// リンクその２
//　まずはリンクの棒２本を作図することを考えます
#VAR
　dmy1 = "---リンク(1)---"　　;dmy1
　px1 = 0　　　　;*位置X
　py1 = 0　　　　;*位置Y
　pa1 = 0　　　　;*角度[°]
　ll1 =50　　　　;*リンク長さ
　lw1 =10　　　　;*リンク幅
　dmy2 = "---リンク(2)---"　　;dmy2
　px2　　　　　　;位置X
　py2　　　　　　;位置Y
　pa2 = 0　　　　;*角度[°]
　ll2 =80　　　　;*リンク長さ
　lw2 =15　　　　;*リンク幅
　// 作業用
　no
　px
　py
　ll
　lw
　pan
　w1
　w2
　w3
　w4
　w5
　w6
　w7
　w8

#DRAW
　LAYER SetLineLay1　　// 外形線
　PEN SetLineCol1,SetLineLtp1,SetLineWid1

　CAL　no = 1
　CAL　pan = pa1/180.0*PI
　CAL　px = px1
　CAL　py = py1
　CAL　ll = ll1
　CAL　lw = lw1
　#GOTO *LINKDRAW
*RET1
　CAL　no = 2
　CAL　px2 = px1 + ll1*Cos(pan)
　CAL　py2 = py1 + ll1*Sin(pan)
　CAL　pan = (pa1+pa2)/180.0*PI
　CAL　px = px2
　CAL　py = py2
　CAL　ll = ll2
　CAL　lw = lw2
　#GOTO *LINKDRAW
*RET2
　#EXIT


// リンク１本を作図
//　　no = 1、2
*LINKDRAW
　CAL　w1 = px
　CAL　w2 = py
　CAL　w3 = lw/2.0
　CAL　w4 = pan + 0.5*PI
　CAL　w5 = pan + 1.5*PI
　ARC　w1,w2,w3,w4,w5

　CAL　w1 = px
　CAL　w2 = py + lw/2.0
　CAL　w3 = px + ll
　CAL　w4 = w2
　GETREV　w5,w6, w1,w2,px,py,pan
　GETREV　w7,w8, w3,w4,px,py,pan
　LINE　w5,w6,w7,w8

　CAL　w1 = px
　CAL　w2 = py - lw/2.0
　CAL　w3 = px + ll
　CAL　w4 = w2
　GETREV　w5,w6, w1,w2,px,py,pan
　GETREV　w7,w8, w3,w4,px,py,pan
　LINE　w5,w6,w7,w8

　CAL　w3 = px + ll
　CAL　w4 = py
　GETREV　w1,w2, w3,w4,px,py,pan
　CAL　w3 = lw/2.0
　CAL　w4 = pan + 1.5*PI
　CAL　w5 = pan + 0.5*PI
　ARC　w1,w2,w3,w4,w5

　#IF ( no == 1 )
　　#GOTO　*RET1
　#END
　#GOTO　*RET2

// リンクその１
//　まずはリンクの棒１本を作図することを考えます
//　長円を描く事を考えます
#VAR
　px = 0　　　　;*位置X
　py = 0　　　　;*位置Y
　pa = 0　　　　;*角度[°]
　ll =50　　　　;*リンク長さ
　lw =10　　　　;*リンク幅
　pan
　w1
　w2
　w3
　w4
　w5
　w6
　w7
　w8

#DRAW
　LAYER SetLineLay1　　// 外形線
　PEN SetLineCol1,SetLineLtp1,SetLineWid1

　CAL　pan = pa/180.0*PI

　CAL　w1 = px
　CAL　w2 = py
　CAL　w3 = lw/2.0
　CAL　w4 = pan + 0.5*PI
　CAL　w5 = pan + 1.5*PI
　ARC　w1,w2,w3,w4,w5

　CAL　w1 = px
　CAL　w2 = py + lw/2.0
　CAL　w3 = px + ll
　CAL　w4 = w2
　GETREV　w5,w6, w1,w2,px,py,pan
　GETREV　w7,w8, w3,w4,px,py,pan
　LINE　w5,w6,w7,w8

　CAL　w1 = px
　CAL　w2 = py - lw/2.0
　CAL　w3 = px + ll
　CAL　w4 = w2
　GETREV　w5,w6, w1,w2,px,py,pan
　GETREV　w7,w8, w3,w4,px,py,pan
　LINE　w5,w6,w7,w8

　CAL　w3 = px + ll
　CAL　w4 = py
　GETREV　w1,w2, w3,w4,px,py,pan
　CAL　w3 = lw/2.0
　CAL　w4 = pan + 1.5*PI
　CAL　w5 = pan + 0.5*PI
　ARC　w1,w2,w3,w4,w5

ひし形の辺の長さを変えること無く対角線を任意に変更出来て外形の変化の軌跡が図面に落とせたら助かります。（今は円の交点を拾ってひし形の変形を書いてますが、とても面倒です）

// 菱形その１
#VAR
　l = 100　　　　;*辺の長さ
　h =　50　　　　;*中心からの高さ
　x　　　　　　　;x
　w1
　w2
　w3
　w4

#DRAW
　LAYER SetLineLay1　　// 外形線
　PEN SetLineCol1,SetLineLtp1,SetLineWid1

　CAL　x = Sqrt(l*l - h*h)

　CAL　w1 = x
　CAL　w2 = 0
　CAL　w3 = 0
　CAL　w4 = h
　LINE　w1,w2,w3,w4

　CAL　w1 = w3
　CAL　w2 = w4
　CAL　w3 =-x
　CAL　w4 = 0
　LINE　w1,w2,w3,w4

　CAL　w1 = w3
　CAL　w2 = w4
　CAL　w3 = 0
　CAL　w4 =-h
　LINE　w1,w2,w3,w4

　CAL　w1 = w3
　CAL　w2 = w4
　CAL　w3 = x
　CAL　w4 = 0
　LINE　w1,w2,w3,w4

// 菱形その２
#VAR
　l = 100　　　　;*辺の長さ
　h1 = 10　　　　;*開始高さ
　h2 = 80　　　　;*終了高さ
　n =　10　　　　;*分割数
　h
　x
　i
　w1
　w2
　w3
　w4

#DRAW
　#IF (l <= 0)
　　BEEP
　　MESSAGE "入力エラー","辺の長さは正の数値で入力して下さい","",0,0
　　#EXIT　
　#END
　#IF ((l*l - h1*h1) < 0)
　　BEEP
　　MESSAGE "入力エラー","開始高さを再入力して下さい","",0,0
　　#EXIT　
　#END
　#IF ((l*l - h2*h2) < 0)
　　BEEP
　　MESSAGE "入力エラー","終了高さを再入力して下さい","",0,0
　　#EXIT　
　#END

　LAYER SetLineLay1　　// 外形線
　PEN SetLineCol1,SetLineLtp1,SetLineWid1

　CAL　h = h1
　CAL　i = 0
　#WHILE (i <= n)
　　CAL　x = Sqrt(l*l - h*h)

　　CAL　w1 = x
　　CAL　w2 = 0
　　CAL　w3 = 0
　　CAL　w4 = h
　　LINE　w1,w2,w3,w4

　　CAL　w1 = w3
　　CAL　w2 = w4
　　CAL　w3 =-x
　　CAL　w4 = 0
　　LINE　w1,w2,w3,w4

　　CAL　w1 = w3
　　CAL　w2 = w4
　　CAL　w3 = 0
　　CAL　w4 =-h
　　LINE　w1,w2,w3,w4

　　CAL　w1 = w3
　　CAL　w2 = w4
　　CAL　w3 = x
　　CAL　w4 = 0
　　LINE　w1,w2,w3,w4

　　CAL　h = h + (h2-h1)/n
　　CAL　i = i + 1
　#END

Script! 18 (LHA自己解凍圧縮；558KB)　すくりぷと（もどき）を作成しておき、それを解釈させて図形を作成し、ＢＭＰやＤＸＦ等の出力を行います。テスト版なので注意！EXEのみ。マウスホイール対応、文字列処理命令等追加、音声合成機能追加(2008.01.11) #IF文拡張・#WHILE文追加(2008/07/16)

スクリプトファイルを実行し、BMP形式／EMF形式／DXF形式／PCES形式/JWS形式で保存したり、[→JWW]ボタンをクリックして JWWクリップボードに転送し、JWWで[貼付]を行うと JWWでその図形を作図することが出来ます。同様に、[→AutoCAD]ボタンをクリックして AutoCADのコマンドライン上で[貼付]を行うとUCS原点上に図形を作図します。機能的には「Script!」と同様です。
「フォルダ／ファイル」タブでは、選択したフォルダ内のスクリプトファイルをダブルクリックする事によって実行する事が出来ます。「登録リスト」タブでは、自分の好きなようにスクリプトファイルを登録することが出来ます。タブは26種類あり、種類毎に分類する事が出来ます。「各種設定」では、本ソフトを「Script!」と同じフォルダに入れておくと「Script!」の設定を読み書きする事が出来ます。
※試用版では、タブ内のファイルは最大10ファイル迄、連続使用時間は３分迄に制限されます。それ以外については正規版と同じです。
※試用版です。
Ver.1.12 2008/07/16　追加変更
・Script!18 にてスクリプト仕様を拡張
　・#IF 文のネスト対応
　・#IF 〜 #ELSE 〜 #END 文の対応
　・#WHILE 〜 #END 文の対応

#VAR
　x1 = 10 　;*点１X座標
　y1 = 0　　;*点１Y座標
　x2 = 100　;*点２X座標
　y2 = 0　　;*点２Y座標
　x3 = 20 　;*点３X座標
　y3 = 50 　;*点３Y座標
　ra1　　　;*角度１[°]
　ra2　　　;*角度２[°]
　// 作業用
　w1
　w2
　an1　　　// 点1〜点2の角度
　an2　　　// 点2〜点3の角度
　an3　　　// 点3〜点1の角度
　ln1　　　// 点1〜点2の長さ
　ln2　　　// 点2〜点3の長さ
　ln3　　　// 点3〜点1の長さ
　wx1
　wy1
　wx2
　wy2
　wx3
　wy3
　wx4
　wy4
　rr
　rx1
　ry1
　rx2
　ry2
　rx3
　ry3
　ran1
　ran2
　
#DRAW
　LAYER SetLineLay1　　// 外形線
　PEN SetLineCol1,SetLineLtp1,SetLineWid1

　// 三角形を描く
　LINE x1,y1,x2,y2
　LINE x2,y2,x3,y3
　LINE x3,y3,x1,y1

　CAL　w1 = x2-x1
　CAL　w2 = y2-y1
　GETANGLE an1,w1,w2
　CAL　w1 = x3-x2
　CAL　w2 = y3-y2
　GETANGLE an2,w1,w2
　CAL　w1 = x1-x3
　CAL　w2 = y1-y3
　GETANGLE an3,w1,w2
　GETDIST ln1,x1,y1,x2,y2
　GETDIST ln2,x2,y2,x3,y3
　GETDIST ln3,x3,y3,x1,y1

　CAL　rr = (ln1+ln2+ln3)/3/50

　LAYER SetLineLay7　　// 補助線
　PEN 6,SetLineLtp7,SetLineWid7
　// 垂心
　CAL　w1 = 200
　CAL　wx1 = x1 + w1*Cos(an2-0.5*PI)
　CAL　wy1 = y1 + w1*Sin(an2-0.5*PI)
　CAL　wx2 = x1 + w1*Cos(an2+0.5*PI)
　CAL　wy2 = y1 + w1*Sin(an2+0.5*PI)
　LINE wx1,wy1,wx2,wy2

　CAL　wx3 = x2 + w1*Cos(an3-0.5*PI)
　CAL　wy3 = y2 + w1*Sin(an3-0.5*PI)
　CAL　wx4 = x2 + w1*Cos(an3+0.5*PI)
　CAL　wy4 = y2 + w1*Sin(an3+0.5*PI)
　LINE wx3,wy3,wx4,wy4

　GETCRSLL w1,rx1,ry1,wx1,wy1,wx2,wy2, wx3,wy3,wx4,wy4
　CIRCLE rx1,ry1,rr

　// 重心
　PEN 4,SetLineLtp7,SetLineWid7
　CAL　wx1 = x1
　CAL　wy1 = y1
　CAL　wx2 = (x2 + x3)/2
　CAL　wy2 = (y2 + y3)/2
　LINE wx1,wy1,wx2,wy2

　CAL　wx3 = x2
　CAL　wy3 = y2
　CAL　wx4 = (x1 + x3)/2
　CAL　wy4 = (y1 + y3)/2
　LINE wx3,wy3,wx4,wy4

　GETCRSLL w1,rx2,ry2,wx1,wy1,wx2,wy2, wx3,wy3,wx4,wy4
　CIRCLE rx2,ry2,rr

　// 外心
　PEN 3,SetLineLtp7,SetLineWid7
　CAL　w1 = 200
　CAL　wx1 = (x1 + x2)/2
　CAL　wy1 = (y1 + y2)/2
　CAL　wx2 = wx1 + w1*Cos(an1+0.5*PI)
　CAL　wy2 = wy1 + w1*Sin(an1+0.5*PI)
　LINE wx1,wy1,wx2,wy2

　CAL　wx3 = (x2 + x3)/2
　CAL　wy3 = (y2 + y3)/2
　CAL　wx4 = wx3 + w1*Cos(an2+0.5*PI)
　CAL　wy4 = wy3 + w1*Sin(an2+0.5*PI)
　LINE wx3,wy3,wx4,wy4

　GETCRSLL w1,rx3,ry3,wx1,wy1,wx2,wy2, wx3,wy3,wx4,wy4
　CIRCLE rx3,ry3,rr

　// オイラー線
　LAYER SetLineLay5　　// 想像線
　PEN 8,SetLineLtp5,SetLineWid5
　LINE rx1,ry1, rx2,ry2
　LINE rx2,ry2, rx3,ry3

　CAL　w1 = rx2-rx1
　CAL　w2 = ry2-ry1
　GETANGLE ran1,w1,w2
　CAL　w1 = rx3-rx2
　CAL　w2 = ry3-ry2
　GETANGLE ran2,w1,w2
　CAL　ra1 = ran1*180/PI
　CAL　ra2 = ran2*180/PI
　// この２つの角度が同じであれば、オイラー線は１直線上にあると言える

Script! 17 (LHA自己解凍圧縮；556KB)　すくりぷと（もどき）を作成しておき、それを解釈させて図形を作成し、ＢＭＰやＤＸＦ等の出力を行います。テスト版なので注意！EXEのみ。マウスホイール対応、文字列処理命令等追加、音声合成機能追加(2008.01.11) 変数諸元名に「線種」「線色」「任意色」「ACAD色」を追加(2008.04.05)

スクリプトファイルを実行し、BMP形式／EMF形式／DXF形式／PCES形式/JWS形式で保存したり、[→JWW]ボタンをクリックして JWWクリップボードに転送し、JWWで[貼付]を行うと JWWでその図形を作図することが出来ます。同様に、[→AutoCAD]ボタンをクリックして AutoCADのコマンドライン上で[貼付]を行うとUCS原点上に図形を作図します。機能的には「Script!」と同様です。
「フォルダ／ファイル」タブでは、選択したフォルダ内のスクリプトファイルをダブルクリックする事によって実行する事が出来ます。「登録リスト」タブでは、自分の好きなようにスクリプトファイルを登録することが出来ます。タブは26種類あり、種類毎に分類する事が出来ます。「各種設定」では、本ソフトを「Script!」と同じフォルダに入れておくと「Script!」の設定を読み書きする事が出来ます。
※試用版では、タブ内のファイルは最大10ファイル迄、連続使用時間は３分迄に制限されます。それ以外については正規版と同じです。
※試用版です。

スクリプトファイルを実行し、BMP形式／EMF形式／DXF形式／PCES形式/JWS形式で保存したり、[→JWW]ボタンをクリックして JWWクリップボードに転送し、JWWで[貼付]を行うと JWWでその図形を作図することが出来ます。同様に、[→AutoCAD]ボタンをクリックして AutoCADのコマンドライン上で[貼付]を行うとUCS原点上に図形を作図します。機能的には「Script!」と同様です。
「フォルダ／ファイル」タブでは、選択したフォルダ内のスクリプトファイルをダブルクリックする事によって実行する事が出来ます。「登録リスト」タブでは、自分の好きなようにスクリプトファイルを登録することが出来ます。タブは26種類あり、種類毎に分類する事が出来ます。「各種設定」では、本ソフトを「Script!」と同じフォルダに入れておくと「Script!」の設定を読み書きする事が出来ます。
※試用版では、タブ内のファイルは最大10ファイル迄、連続使用時間は３分迄に制限されます。それ以外については正規版と同じです。
※試用版です。
Ver.1.10 2008/05/23　追加変更
・ArcSin、ArcCos の修正